peaks(x,y) = 3*(1-x)**2*exp(-x**2 - (y+1)**2)\
             - 10*(x/5.0 - x**3 - y**5)*exp(-x**2 - y**2)\
             - exp(-(x+1)**2 - y**2)/3

set macros
JET="define (0 0 0 0.5, 1./8 0 0 1, 3./8 0 1 1, 5./8 1 1 0, 7./8 1 0 0, 1 0.5 0 0)"
COPPER="defined (0 0 0 0, 0.8 1 0.64 0.4, 1 1 0.8 0.5)"
OCEAN="defined (0 0 0 0, 1./3 0 0 1./3, 2./3 0 0.5 2./3, 1 1 1 1)"
HOT="defined (0 0 0 0, 0.4 1 0 0, 0.8 1 1 0, 1 1 1 1)"
COOL="defined (0 0 1 1, 1 1 0 1)"
SPRING="defined (0 1 0 1, 1 1 1 0)"
SUMMER="defined (0 0 0.5 0.4, 1 1 1 0.4)" 
AUTUMN="defined (0 1 0 0, 1 1 1 0)"
WINTER="defined (0 0 0 1, 1 0 1 0.5)"
BONE="defined (0 0 0 0, 3./8 21.0/64 21./64 29./64, 3./4 21.0/32 25./32 25./32)"
RAINBOW="defined (0 1 0 0, 0.4 1 1 0, 0.6 0.5 1 0, 0.8 0 0 1, 1 2./3 0 1)"
PINK="defined (0 0 0 0, 3./8 7./12 1./4 1./4, 3./4 5./6 5./6 1./2, 1 1 1 1)"

set xyplane 0
set xr [-3:3]
set yr [-3:3]
unset border
unset key
unset tics
unset colorbox
set samples 32
set isosample 32
set pm3d hidden3d 100 depthorder
set style line 100 lt -1 lw 0.1 lc rgb "black"
set view 50,30,1.2,1.4
set term pngc enh font "Arial,5" size 600,600 background rgb "#223322"
set out "colormap.png"
set label 1 at 3,-3,-3 font "Arial,11" front tc rgb "white"

colormap ="JET RAINBOW BONE HOT COOL COPPER \
           OCEAN PINK SPRING SUMMER AUTUMN WINTER"

set multiplot lay 4,3
do for [i=1:12] {
set label 1  word(colormap,i) 
eval sprintf("set palette @%s", word(colormap,i))
splot peaks(x,y) w pm3d
}
unset multiplot

!display colormap.png

# set palette rgb R,G,B
#
# OCEAN  23,26,3
# HOT    21,22,23
# COOL   3,-3, 2
# SPRING 2,3,-3
# AUTUMN 2,3,0