rho(x) = (tan(pi/4-x/2)/tan(pi/4-a0/2))**n/tan(a0)
lx(a,o) = rho(a)*sin(n*(o-o0))
ly(a,o) = rho(a0) - rho(a)*cos(n*(o-o0))

set term pngc enh font "Times,10" size 480,480
set out "lambert.png"

set parametric
set border lc rgb "white"
set tics out format "%.0f" tc rgb "white"
unset key
a0 = 35*pi/180
o0 = 135*pi/180
n = sin(a0)
sc = 0.2
set xr [-sc/2:sc]
set yr [-sc/2:sc]
do for [i=0:4] {
eval sprintf("set label '%d' at %f,-0.112 tc rgb 'gray'", \
              131+4*i, -0.068+i*0.061) 
eval sprintf("set label '%d' at -.114,%f tc rgb 'gray'", \
              31+4*i, -0.066+i*0.071) 
}

set multiplot
set tr [-sc/2:sc] 
plot  t,0.2  w filledc y1=-0.2 lc rgb "web-blue" 
plot  'world_50m.txt' \
       u (lx($2*pi/180,$1*pi/180)):(ly($2*pi/180,$1*pi/180))\
       w filledc lc rgb "khaki" 
set tr [125:160]
do for [i=0:10] {
plot (lx((31+2*i)*pi/180,t*pi/180)),(ly((31+2*i)*pi/180,t*pi/180)) \
     w l lt 0 
}
set tr [28:48]
do for [i=0:14] {
plot (lx(t*pi/180, (123+2*i)*pi/180)),(ly(t*pi/180,(123+2*i)*pi/180)) \
     w l lt 0 
}
unset multiplot

! display lambert.png