星座早見表

Ｑ：グルグル動く星座早見表みたいなものを描きたいのですが．
Ａ：splotで素直に天球座標系の星を描けばよいでしょう．ただし，内側から見 た図にするには，赤経を負にして描かなければなりません．なお，日本の都道府県別の人口の棒グラフの場合と同様に， 星の位置データと星座の境界線データが問題ですが，天文関係のデータはけっこ う公開されているので助かります．

• 参考文献等
  • 早野龍五，高橋忠幸：計算物理，（共立出版）
  • 物理のかぎしっぽ - 天文学 - Gnuplotでプラネタリウム
  • 星のデータとしては Yale Bright Star Catalogue が有名．上記，物理のか ぎしっぽのページにも入手先が紹介されている．ここでは次のサイトをあ げておきます．
    ftp://cdsarc.u-strasbg.fr/pub/cats/V/50/
  • 国際天文学連合が定めた星座境界のデータとしては，bound_18.dat(1875年) がいろいなサイトで引用されていますが，以下のサイトではさらに細かい bound_20.datなども入手できます．
    ftp://cdsarc.u-strasbg.fr/pub/cats/VI/49/
  • 以下のスクリプトの実行に必要なデータ（BSC5とbound_18.datから作成したもの）
    positions.dat, bound_20.dat
  
  
• X11端末はあまり綺麗な描画ができません．Ver. 4.4 で導入されたwxt端末の例 を示します．constellation.plt

  # define convert functions
  set object rectangle from screen 0,0 to screen 1,1 behind fc rgb "#000033"
  set style line 1 lc rgbcolor "#F0FFFF"
  set style line 2 lc rgbcolor "#c0cccc"
  set style line 5 lc rgbcolor "#006666"
  set mapping spherical
  set parametric
  set isosamples 18,36
  set ticslevel 0
  R=1.75
  set size R,R
  set origin -0.375,-0.38
  set hidden3d
  set borde 0
  unset tics
  set angles degree
  set nokey
  set term wxt size 512,512
  set urange [0:180]
  set vrange [-360:0]
  
  splot sin(u)*cos(v), sin(u)*sin(v), cos(u) ls 5 lw 0,\
        "bound_20.dat" using (-($1)*15.0):2 w l lt 1 lw 0.25,\
        "positions.dat" using (($3 < 1.0) ? (-$1): 1/0):2 ls 1 pt 7 ps 1.0,\
        "" using ((1.0 <= $3 && $3 < 2.0) ? (-$1): 1/0):2 ls 1 pt 7 ps 0.7,\
        "" using ((2.0 <= $3 && $3 < 3.0) ? (-$1): 1/0):2 ls 1 pt 7 ps 0.5,\
        "" using ((3.0 <= $3 && $3 < 4.0) ? (-$1): 1/0):2 ls 1 pt 7 ps 0.4,\
        "" using ((4.0 <= $3 && $3 < 5.0) ? (-$1): 1/0):2 ls 2 pt 7 ps 0.3
  #      "" using ((5.0 <= $3 && $3 < 6.0) ? (-$1): 1/0):2 lt 3 pt 7 ps 0.2
  
  pause -1 "Hit the return key!"
  

• 得られる図：中央にオリオン座が見えます