漢字の表示

Ｑ：漢字の表示はできますか？

Ａ：Postscript,png,gif,jpeg,tgif,wxtなどの端末では可能です．ただし，描 画に用いられているライブラリ等により漢字フォントの扱いが異なることを反映 して，同じ物理フォントでも，異なった名前で呼び出さなければならない点に注 意が必要です．

PostScript端末の漢字表示

パッチをあてなければ無理と頭から決めてかかっていた のですが，ちょこっと試したら，簡単に漢字が表示できました． どのバージョンから可能になったのか定かではありません (^^;

• ソース kanji.plt

  set title "日本語のフォントが使えます" font "Ryumin-Light-EUC-H,40"
  set xlabel "X軸：Alias-Mincho" font "Alias-Mincho-EUC-H,28"
  set ylabel "Y軸：Alias-Gothic" font "Alias-Gothic-EUC-H,28"
  set term postscript eps color "Times-Roman" 20 
  set label "文字の回転" at 0,0.5 rotate by 30 font \
       "GothicBBB-Medium-EUC-H,34" front tc lt 1
  set out "kanji.eps" 
  plot (sin(x)/x)**2 w filledcurves lt 3
  

• 出力結果
  
  

PNG端末の漢字表示

gdライブラリを -DJISX0208 付きでコンパイルすると，日本語TTFが扱えるように なります．このライブラリであれば，簡単に漢字が表示できました．どのバージョ ンから可能になったのか定かではありません (^^;

• ソース pngkanji.plt

  set term png transparent size 360,252 \
      font "/usr/lib/X11/fonts/TrueType/ipam.ttf" 8
  set title "日本語のフォントが使えます" font "ipam.ttf, 16" 
  set xlabel "X軸：IPAゴシック" font "ipag.ttf,12" 
  set ylabel "Y軸：リョービ羽衣" font "tchagom.ttc, 12" 
  set label "文字の回転" at 0,0.5 font "VL-Gothic-Regular.ttf,16" \
      rotate by 30 front tc lt 1 
  set out "pngkanji.png" 
  plot (sin(x)/x)**2 w filledcurves lt 3
  

• 出力結果
  
  

wxt端末の漢字表示

使えるフォントの種類はfc-listコマンドで調べられます．

• ソースwxtkanji.plt

  set title "日本語のフォントが使えます" font "IPAMincho,20"
  set xlabel "X軸：IPAゴシック {/Symbol q}" font "IPAGothic,14"
  set ylabel "Y軸：リョービHGゴシックE {/Symbol W(q)}" font "HGGothicE,14"
  set term wxt enh size font "Times,10" 480,360 
  set label "文字の回転" at 0,0.5 rotate by 30 font \
      "VL PGothic,20" front tc lt 1
  plot (sin(x)/x)**2 w filledcurves lc rgb "#3399cc"
  pause -1
  

• 出力結果