確かにできませんね。CVS 版 (4.3) でもだめなようです。ドキュメントには
「splot はだめ」とは書いてないので、もしかしたらバグかもしれません。

一応 multiplot を使って、splot では key title を書かずに、plot に
書かせる、というごまかしは可能です:

reset
set multiplot
unset key
splot "test.dat" using 1:2:3
set key
unset border
unset tics
plot [0:1][0:1] "test.dat" using 1:(1/0) title 2
unset multiplot

のむら> （実際には、１つのデータファイルにおさめた３次元データの時間発展データから、
のむら> everyオプションを使ってアニメーション表示する際に、
のむら> 画面上のタイトルに、何ステップ目かを表示したいのです。）

こういう目的の場合、私ならば key title ではなくて、全体のタイトル
として何ステップ目かを表示させるでしょう。今は文字列変数、文字列値
関数が使えるので、そういうことも楽にできるようになりました:

### f1.gp
titlestr(n)=sprintf("%d step",n)
set xrange [0:1]
set yrange [0:1]
set zrange [0:1]
set pointsize 5

set term gif animate
set out 'anim.gif'
a=0
load 'f2.gp'
set out

### f2.gp
a=a+1
set title titlestr(a)
splot 'data.txt' using 1:2:3 every ::a::a w p
if (a<5) reread

この f2.gp の方を、set title するかわりに

splot 'data.txt' using 1:2:3 every ::a::a title titlestr(a) w p

とすれば、key title の方が変わってくれます。

〔ツリー構成〕

【1656】 splotのtitleにデータファイルの文字列を渡したい 2007/11/2(金)13:40 のむら (868) ≪

┣【1657】 re(1):splotのtitleにデータファイルの文字列を渡したい 2007/11/2(金)17:43 竹の (1237)

┣【1658】 re(2):splotのtitleにデータファイルの文字列を渡したい 2007/11/2(金)20:33 竹の (232)

┣【1665】 re(3):splotのtitleにデータファイルの文字列を渡したい 2007/12/4(火)22:12 松田七美男 (159)

┣【1667】 re(4):splotのtitleにデータファイルの文字列を渡したい 2007/12/5(水)08:46 竹の (737)

┣【1680】 re(5):splotのtitleにデータファイルの文字列を渡したい 2007/12/6(木)21:19 竹の (135)

┣【1660】 re(2):splotのtitleにデータファイルの文字列を渡したい 2007/11/5(月)13:23 のむら (530)