unset k
set yr [0:]
dat = "histo.dat"
set st fill so 0.7
set t pngc enh font "Arial,6" size 480,360
set ou "multi_histograms.png"
set multi lay 2,2 ti "Histograms" font "Arial,16"
# 1,1
set st hist clustered
set label 1 "clustered" at 1,3 font ",14" front
plot for [col=2:5] dat u col:xticlabels(1) w histo
# 1,2
set st hist rowstacked
set la 1 "rowstacked" at 1,7 font ",14" front
set boxwidth 0.5 relative
plot for [col=2:5] dat u col:xtic(1) w histo
# 2,1
set st histo rowstacked
set la 1 "rowstacked" at 1,50 font ",14" front
set boxwidth 0.5 relative
set yr [0:100]
p \
dat u (s=$2+$3+$4+$5, (($2)/s)*100) w histo, \
dat u (s=$2+$3+$4+$5, (($3)/s)*100) w histo, \
dat u (s=$2+$3+$4+$5, (($4)/s)*100) w histo, \
dat u (s=$2+$3+$4+$5, (($5)/s)*100):xtic(1) w histo
# 2,2
set auto y
do for [i=0:4] {
  set lt i+1 lc rgb sprintf("#%02X%02X%02X", 0, 50*i, 250-50*i)
}
set st hist columnstacked
set la 1 "columnstacked" at 0,10 font ",14" front
set boxwidth 0.5 relative
set xti ("2001" 0, "2002" 1, "2003" 2, "2004" 3)
plot for [col=2:5] dat u col w histo ls 5
unset multi

#
# "histo.dat" (utf-8)
#
# 東京    1 6 2 3
# 神奈川  2 5 1 5
# 千葉	  3 4 2 3
# 埼玉    4 3 1 5
# 茨城	  5 2 2 3