画面表示とプリンタ印刷物との一致

Ｑ：画面上の図と論文に挿入するためのPostscript形式の図をなるべく同じ にするにはどうしたらいいでしょうか？

Ａ１：Postscript形式の図を作成するスクリプトの最後にPSビューアを起動するコマ ンドを追加して，その都度確かめて微調整するのが最も手堅い方法です． しかし，例えば講義の画面デモ表示とreplotにより教材に挿入する Postscript形式の出力を一つのスクリプトで済ませたいならば，文字指定とサイズ 指定をしっかりする必要があります．また，その時にはPostscriptは，EPS ではなく縦書き(Portrait)のPSを使いましょう．

set term wxt enh font "name,size" size sizex,sizey
set term post enh font "name,size" size sizex,sizey color port

• スクリプト：sameprint.plt

  set term wxt enh font "Times,10" size 480,360
  set xlabel "{/Ryumin-Light-EUC-H=14 x軸のラベル}"
  set ylabel "{/GothicBBB-Medium-EUC-H=14 y軸のラベル}"
  plot [0:10] \
  besj0(x) w l lw 2 lc rgb "#009900",\
  besj0(x) w p pt 6 ps 1 lc rgb "#990000"
  
  set term post enh font "Times,10" size 4.8,3.6 port color
  set out "sameprint.eps"
  replot
  system("gv sameprint.eps")
  

• 得られた画像
  

Ａ２：multiplotで複数の図をPostscript形式で出力し，その微調整を行う場合， 同じ調整コマンドを何度も書き直すのは大変です．その場合は，Ver.4.2から導 入されたマクロ（文字列の置換）を用いましょう．

set macros
macroname = "strings"

• スクリプト：samemultiprint.plt

  set macros
  ########################################################################
  st1 = "lw 1.6 lt 1 lc rgb '#006666'"
  st2 = "lw 1.6 lt 1 lc rgb '#990000'"
  sc1 = "scale 0.95,0.95"
  cmd1 = "plot sin(x) w lp pt 2 ps 0.6"
  cmd2 = "plot besj0(x) w p pt 6 ps 0.6"
  cmd3 = "plot 1/(1+x**2) w step" 
  cmd4 = "plot exp(-0.1*x**2) w im"
  setbg = "set object 1 rect from sc 0, sc 0 to sc 1, sc 1 \
           lw 0 behind fc rgb 'beige'"
  unsetbg = "unset object 1"
  ########################################################################
  set xlabel "X軸の名前：ゴシック" font "GothicBBB-Medium-EUC-H,8"
  set ylabel "Y軸の名前：明朝" font "Ryumin-Light-EUC-H,8"
  
  set term wxt enh font "Helvetica,6" size 480,360
  @setbg
  set multiplot layout 2,2 @sc1
  @cmd1 @st1
  @unsetbg
  @cmd2 @st2
  @cmd3 @st1
  @cmd4 @st2
  unset multiplot
  
  set term post enh font "Helvetica,6" size 4.8,3.6 port color
  set out "samemultiprint.eps"
  @setbg
  set multiplot layout 2,2 @sc1
  @cmd1 @st1
  @unsetbg
  @cmd2 @st2
  @cmd3 @st1
  @cmd4 @st2
  unset multiplot
  system("gv samemultiprint.eps")
  

• 得られた画像