３次元の軌道上を点が動くアニメーション

Ｑ：３次元の軌道上を点が動いていくアニメーション作成する方法を教えてくだ さい

Ａ０： Gnuplotting/tag/animation を覗くことをまずお薦めします．

Ａ１：バージョン4.6以降では，gdライブラリが対応している場合には，gif terminalにanimateオプションを付けてで直接作成できます．すなわち，

set term gif animate {delay n} {loop n} {{no}optimize} ...

と指定しておき，シーン毎の静止画を次々と描画すればよいのです．

あるいは，pngcairoやjpegなどで連続するシーンの静止画像を作成しておいて， 後で外部ツールなどで，アニメーションGIFに変換するのも一法です．Unix系で は，ImageMagickのconvertが便利です．例えば，

convert -adjoin {-delay n} img***.png img.gif

などのコマンドをgnuplotのsystem()で呼び出せば，gnuplotのスクリプト だけで作成可能です．pngcairoで生成されるpng画像の方が品質が高いです． 「軌道上の点の動き」ではありませんが，以下に例を示します．

• １次元無限領域における拡散の時間発展に関する基本関数
  
  
• pngcairo terminalで作成したpng画像をまとめたもの．曲線が滑らかです．
  
  
• Pm3dのlightingオプションを用いると，かなり面白いものが描けます．
  
  

Ａ２：開発バージョン3.8では，splot に対しても every や multiplot がサポー トされました．したがって，3.7までの plot と同様に1つのデータファイルを用 意しておき，reread を用いたループ中で every により指定した位置からデータ を読み出して点を表示できます．すなわち３D軌道上を点が動くアニメーション が可能です．

• スクリプト：２つのファイル prepare.plt と main.plt が必要 です．
  
  gnuplot prepare.plt
  と実行します．

  ### prepare.plt ###
  samp=100
  set xrange[-10:10]
  set yrange[-10:10]
  set zrange[-100:100]
  set term table
  set out 'trajectory.dat'
  set parametric
  set samples samp
  set trange[0:11]
  plot t*cos(t), t*sin(t)
  #splot x**2-y**2
  set out 'surface.dat'
  set noparametric
  set isosamples 21,21
  set samples 30
  splot x**2-y**2
  set out
  set term x11
  set nomouse
  set pointsize 2
  set ticslevel 0
  set nokey
  set view 30,45,,1.2
  i=0
  j=0
  load "main.plt"
  

  ### main.plt ###
  interval=0.05
  set multiplot; \
  set noparametric; set hidden3d; splot "surface.dat" w lines; \
  set parametric; set nohidden3d; \
  splot "trajectory.dat" using 1:2:($1**2-$2**2) every 1:1:i:0:i:0 lt 1 pt 7,\
        "trajectory.dat" using 1:2:($1**2-$2**2) w lines lt 3 ; \
  set nomultiplot
  if (i < samp) i=i+1; pause interval; reread
  exit
  

• アニメーション途中の様子を以下に示します．
  
• Pm3d/lighting を用いるともっと見映えのするものができます．