plot のスタイルに vector がありますので，それをお使いになるのがいいでしょう．
各ベクトルを描くには，ベクトルの始点とベクトルの成分の計４つのデータが
１行に並んでいる必要があります．始点のデータとベクトルのデータは，物理量
の次元が異りますから，どちらかをスケーリングできるようにしないと綺麗な
図になりません．次の放物運動の例でいろいろ確かめてください(vsc の値)．

*** parabolic.plt ***
set nokey
vsc=0.3
V0=20; th=pi/3;
V0x=V0*cos(th);
V0y=V0*sin(th);
g=9.8
vx(t)=V0x
vy(t)=V0y-g*t
x(t)=V0x*t
y(t)=V0y*t-0.5*g*t**2
tm=V0y*2/g
set parametric
set trange[0:tm]
set term table
set out "parabr.dat"
plot x(t),y(t)
set out "parabv.dat"
plot vx(t), vy(t)
!paste parabr.dat parabv.dat > parab.dat
set term X11
plot "parab.dat" w lines lt 5,\
"" every 10:1 using 1:2:($4*vsc):($5*vsc) w vector lw 2
pause -1



$ gnuplot parabolic.plt

〔ツリー構成〕

【148】 続・初歩的な質問ですが・・・・ 2004/6/29(火)11:58 一初心者です (285) ≪

┣【149】 re(1):続・初歩的な質問ですが・・・・ 2004/6/29(火)14:29 松田七美男 (836)

┣【150】 re(2):続・初歩的な質問ですが・・・・ 2004/6/29(火)14:45 一初心者です (269)

┣【151】 re(3):続・初歩的な質問ですが・・・・ 2004/6/29(火)15:22 松田七美男 (330)

┣【153】 re(4):続・初歩的な質問ですが・・・・ 2004/6/29(火)20:51 竹の (364)

┣【155】 re(5):続・初歩的な質問ですが・・・・ 2004/6/29(火)21:21 松田七美男 (240)

┣【160】 re(6):続・初歩的な質問ですが・・・・ 2004/6/30(水)17:49 竹の (702)

┣【166】 re(7):続・初歩的な質問ですが・・・・ 2004/6/30(水)21:28 松田七美男 (83)