２次元グラフ: plot

set xlabel "X-axis" font "Helvetica,24"
set ylabel "Y-axis" font "Times,24"
plot [-2*pi:2*pi] sin(x) w lp, "cos.dat" pt 6 ps 2
pause -1
# 以下はイメージを得るためのスクリプト
set term postscript eps color enhanced
set out "plot2d.eps"
replot
!convert plot2d.eps plot2d.png



３次元グラフ: splot 

set isosamples 40,40 # 既定は 10
set ticslevel 0  # 既定は 0.5
set hidden3d # 既定は nohidden3d（隠線処理なし）
set xlabel "X-axis" font "Helvetica,24"
set ylabel "Y-axis" font "Times,24"
set zlabel "q(x)" font "Symbol,24"
set view 70,20,1,1 # 既定は 60,30,1,1
splot sin(x)*sin(y)/x/y
pause -1
# 以下はイメージを得るためのスクリプト
set term post eps color enh
set out "plot3d.eps"
replot
!convert plot3d.eps plot3d.png


等高線図: set contour 

set isosamples 50,50 # 既定は 10
set xlabel "X-axis" font "Helvetica,24"
set ylabel "Y-axis" font "Times,24"
set noztics
set nosurface
set key outside 
set view 0,0,, # 既定は 60,30,1,1
set contour
set cntrparam levels increment -1,0.2,1
splot 3*sin(x)*sin(y)/x/y
pause -1
# 以下はイメージを得るためのスクリプト
set term post eps color enh 
set out "contour.eps"
replot
!convert contour.eps contour.png


マルチプロット: set multiplot 

set term post eps color enh
set out "multi.eps"
set nokey

### set multiplot と set nomultiplot で囲む
set multiplot

set origin 0,0.5
set size 0.5,0.5
set xtics 
set xlabel "X-axis" font "Helvetica,16"
set ylabel "Y-axis" font "Times,16"
plot [-2*pi:2*pi] sin(x) w lp, "cos.dat" pt 6 ps 1

set origin 0.5 ,0.5
set size 0.5,0.5
set isosamples 25,25 # 既定は 10
set ticslevel 0  # 既定は 0.5
set hidden3d # 既定は nohidden3d（隠線処理なし）
set xlabel "X-axis" off 0,-1 font "Helvetica,16"
set ylabel "Y-axis" off 0,-1 font "Times,16"
set zlabel "q(x)" "Symbol,16" rotate by 90
set view 70,20,, # 既定は 60,30,1,1
splot sin(x)*sin(y)/x/y

set origin 0,0
set size 0.5,0.5
set isosamples 50,50 # 既定は 10
set xlabel "X-axis" off 0,0 font "Helvetica,16"
set ylabel "Y-axis" off 0,0 font "Times,16"
set noztics
set nosurface
set view 0,0,, # 既定は 60,30,1,1
set contour
set cntrparam levels increment -1.0,0.2,1.0
splot 3*sin(x)*sin(y)/x/y

# 初期に戻す
reset
set origin 0.5 ,0.0
set size 0.5,0.5
set nokey
set label "Available afer Ver. 3.8e" at -10,-5,1.4 \
    font "Roman,24"
# Ver 3.8e 以降はカラーマップ pm3d が使えます．
set pm3d at s solid explicit 
set palette rgb 7,7,8
set cbrange[-0.4:1.4]
set cbtics -0.2,0.4,1.4
set isosamples 40,40 # 既定は 10
set ticslevel 0  # 既定は 0.5
set xlabel "X-axis" off 0,-1 font "Helvetica,16"
set ylabel "Y-axis" off 0,-1 font "Times,16"
set zlabel "q(x)" font "Symbol,16" rot by 90
set view 45,30,1,1.2 # 既定は 60,30,1,1
splot sin(x)*sin(y)/x/y  w pm3d 

###
set nomultiplot

!convert multi.eps multi.png