たぶん，このようなご質問があると思い，origin の設定云々を申し上げたのですが．
枠を少し狭くして，それぞれの原点(origin)の位置を調整するのはどうでしょう．
X11ではフォントの大きさの調節が難しいので，PostScript を例にしてみました．

set term post eps "Times-Roman" 12
set out 'lateral.eps'
set yrange [-4:4]
NX = ((82-18)+(1985-1837))*1.05
X1 = (82-18)/NX; print X1
X2 = (1985-1837)/NX; print X2
LM = 4
set rmargin 0
set multiplot
set origin 0.04,0
set size X1, 1
set format y "%.0f"
set lmargin X1*LM
set xtics 20, 10, 80
set xrange [18:82]
plot 1
set origin X1+0.02, 0
set size X2, 1
set format y ""
set lmargin X2*LM
set xtics ('' 1840, 1850, '' 1860, '' 1870, '' 1880, '' 1890, 1900, 1950)
set xrange [1837:1985]
plot 2
unset multiplot
!gv 'lateral.eps'

〔ツリー構成〕

【1031】 グラフ２枚を横に並べるときの微調整について。。。 2005/10/12(水)19:18 エルフ (836) ≪

┣【1032】 re(1):グラフ２枚を横に並べるときの微調整について。。。 2005/10/12(水)21:43 松田七美男 (392)

┣【1033】 re(2):グラフ２枚を横に並べるときの微調整について。。。 2005/10/12(水)22:19 エルフ (387)

┣【1034】 re(3):グラフ２枚を横に並べるときの微調整について。。。 2005/10/12(水)23:19 松田七美男 (710)

┣【1035】 re(4):グラフ２枚を横に並べるときの微調整について。。。 2005/10/12(水)23:31 松田七美男 (119)

┣【1040】 re(4):グラフ２枚を横に並べるときの微調整について。。。 2005/10/13(木)20:45 エルフ (360)

┣【1041】 re(5):グラフ２枚を横に並べるときの微調整について。。。 2005/10/13(木)22:57 松田七美男 (755)

┣【1049】 re(6):グラフ２枚を横に並べるときの微調整について。。。 2005/10/14(金)23:56 エルフ (112)