竹のさんの関数と擬似データを使って，最初の質問にあるリンクの見本に近い
ものができました（z^3-1）．絶対値を明度v[0:1]にスケーリングするには，
絶対値の最大値が必要ですが，これが結構手間でした．また，絶対値を[0:1]
にスケーリングした後，ガンマが１では暗いので，v = |z|^(0.1)にしています．

set term png truecolor
set out 'z3m1.png'
unset key
set view map
set size square

hsvcomp(h,s,v,a,b,c,d,e) = (k=floor(h*6), f=h*6-k, (k==a || k==b)? v: \
(k==c || k==d)? v*(1.0-s): \
(k==e)? v*(1.0-f*s): \
v*(1.0-(1.0-f)*s))
hsv2r(h,s,v)=hsvcomp(h,s,v,0,5,2,3,1)
hsv2g(h,s,v)=hsvcomp(h,s,v,1,2,4,5,3)
hsv2b(h,s,v)=hsvcomp(h,s,v,3,4,0,1,5)

# z^3 - 1
I={0,1}
h(x,y) = (ret = arg((x+I*y)**3-1)/(2*pi), (ret < 0) ? ret + 1: ret )
v(x,y) = (abs((x+I*y)**3-1)/75)**0.1
set xrange[-3:3]
set yrange[-3:3]

z2rgb(x,y) = 65536*int(255*hsv2r(h(x,y),1,v(x,y))) \
+ 256*int(255*hsv2g(h(x,y),1,v(x,y))) \
+ int(255*hsv2b(h(x,y),1,v(x,y)))

set pointsize 0.2
set samples 200
set isosamples 200
splot "++" using 1:2:1:(z2rgb($1,$2)) w p pt 5 lc rgbcolor variable
set out

〔ツリー構成〕

【2182】 複素数データの表示 2010/2/11(木)15:58 たけもと (893) ≪

┣【2183】 re(1):複素数データの表示 2010/2/12(金)09:57 松田七美男 (1899)

┣【2184】 re(2):複素数データの表示 2010/2/12(金)18:04 竹の (1903)

┣【2185】 re(3):複素数データの表示 2010/2/12(金)19:34 松田七美男 (116)

┣【2186】 re(3):複素数データの表示 2010/2/12(金)21:54 松田七美男 (508)

┣【2187】 re(4):複素数データの表示 2010/2/13(土)16:33 竹の (1240)

┣【2188】 re(5):複素数データの表示 2010/2/13(土)19:55 松田七美男 (89)

┣【2189】 re(5):複素数データの表示 2010/2/13(土)22:24 松田七美男 (1060)

┣【2190】 re(6):複素数データの表示 2010/2/14(日)16:15 竹の (1553)

┣【2191】 re(7):複素数データの表示 2010/2/16(火)09:58 竹の (1923)

┣【2616】 re(3):複素数データの表示 2012/11/15(木)20:23 竹の (470)