pm3d が絡まない場合については，

http://ayapin.film.s.dendai.ac.jp/~matuda/Gnuplot/Tips/tips.html#trajectory

を参照ください．

splot でまとめて書こうとすると，pm3d は困ったちゃんでして，
他のplotを覆ってしまいます．multiplot を用いれば，pm3d の上に
他の図を載せることができます．次のデモでご確認ください．

set parametric
set term table
set out "2d.dat"
plot sin(1.5*t), cos(t)
set noparametric
set nokey
set xtics 0.2
set ytics 0.2
set xrange[-1:1]
set yrange[-1:1]
set zrange[-50:100]
set view map
set term x11
set out
set hidden3d
set contour surface
set ticslevel 0
set isosamples 30
set pm3d at b
f(x,y)=sin(10*x)*sin(10*y)/x/y
set multiplot
set origin 0,0
set size 1,1
splot [-1:1][-1:1] f(x,y) w pm3d, f(x,y)
set origin 0,0
set size 1,1
set nocolorbox
splot "2d.dat" using 1:2:(50) w l lt 2 lw 2
set nomultiplot
pause -1

〔ツリー構成〕

【1169】 3-dと2-dを混在表示させる方法について 2006/1/22(日)17:07 S (923) ≪

┣【1170】 re(1):3-dと2-dを混在表示させる方法について 2006/1/22(日)18:47 竹の (68)

┣【1172】 re(2):3-dと2-dを混在表示させる方法について 2006/1/22(日)22:30 S (788)

┣【1173】 re(3):3-dと2-dを混在表示させる方法について 2006/1/23(月)09:02 竹の (194)

┣【1174】 re(3):3-dと2-dを混在表示させる方法について 2006/1/23(月)17:31 松岡 (572)

┣【1176】 re(3):3-dと2-dを混在表示させる方法について 2006/1/23(月)20:43 松田七美男 (832)

┣【1177】 re(3):3-dと2-dを混在表示させる方法について(解決) 2006/1/23(月)23:37 S (1206)